asomiya 0.2.0

নিয়ন্ত্ৰণ

লুপ

যেতিয়ালৈকে মানে “যিমান সময়লৈকে”। চৰ্ত সঁচা হৈ থকালৈকে ব্লকটো বাৰে বাৰে চলে।

সঁচা হৈ থকালৈকে

ধৰা ক = ১
ধৰা যোগফল = ০
যেতিয়ালৈকে (ক <= ১০) {
    যোগফল = যোগফল + ক
    ক = ক + ১
}
কোৱা("১ ৰ পৰা ১০ লৈ যোগফল:", যোগফল)
ফলাফল
১ ৰ পৰা ১০ লৈ যোগফল: ৫৫
dhora k = 1
dhora jugfol = 0
jetialoike (k <= 10) {
    jugfol = jugfol + k
    k = k + 1
}
kowa("1-10 jugfol:", jugfol)
ফলাফল
1-10 jugfol: 55

সাৱধান

চৰ্তৰ চলকটো সলনি কৰিবলৈ নাপাহৰিব, নহ’লে লুপটো কেতিয়াও শেষ নহয়। প্ৰায় ১ কোটি খোজৰ পিছত অসমীয়াই এনে প্ৰগ্ৰাম ৰখাই দিয়ে (R008), আৰু প্লেগ্ৰাউণ্ডত ৰখোৱা বুটাম আছে।

আগতেই ৰখাওক: ৰখা

ৰখা-ই লগে লগে লুপৰ পৰা ওলাই আহে:

ধৰা ন = ১
যেতিয়ালৈকে (সঁচা) {
    যদি (ন * ন > ৫০) {
        ৰখা
    }
    ন = ন + ১
}
কোৱা("প্ৰথম সংখ্যা যাৰ বৰ্গ ৫০ তকৈ বেছি:", ন)
ফলাফল
প্ৰথম সংখ্যা যাৰ বৰ্গ ৫০ তকৈ বেছি: ৮
dhora n = 1
jetialoike (xosa) {
    jodi (n * n > 50) {
        rokha
    }
    n = n + 1
}
kowa("first number whose square > 50:", n)
ফলাফল
first number whose square > 50: 8

এৰি যাওক: আগবাঢ়া

আগবাঢ়া-ই এই পাকৰ বাকী অংশ এৰি পৰৱৰ্তী পাক আৰম্ভ কৰে:

ধৰা ক = ০
যেতিয়ালৈকে (ক < ১০) {
    ক = ক + ১
    যদি (ক % ২ == ০) {
        আগবাঢ়া
    }
    কোৱা(ক)
}
ফলাফল
১
৩
৫
৭
৯
dhora k = 0
jetialoike (k < 10) {
    k = k + 1
    jodi (k % 2 == 0) {
        aagbara
    }
    kowa(k)
}
ফলাফল
1
3
5
7
9

লুপৰ ভিতৰত লুপ

ধৰা শাৰী = ১
যেতিয়ালৈকে (শাৰী <= ৪) {
    ধৰা ৰেখা = ""
    ধৰা গণনা = ০
    যেতিয়ালৈকে (গণনা < শাৰী) {
        ৰেখা = ৰেখা + "★"
        গণনা = গণনা + ১
    }
    কোৱা(ৰেখা)
    শাৰী = শাৰী + ১
}
ফলাফল
★
★★
★★★
★★★★
dhora xari = 1
jetialoike (xari <= 4) {
    dhora rekha = ""
    dhora gonona = 0
    jetialoike (gonona < xari) {
        rekha = rekha + "★"
        gonona = gonona + 1
    }
    kowa(rekha)
    xari = xari + 1
}
ফলাফল
★
★★
★★★
★★★★

ৰখা আৰু আগবাঢ়া-এ কেৱল আটাইতকৈ ভিতৰৰ লুপটোতহে প্ৰভাৱ পেলায়। লুপৰ বাহিৰত ব্যৱহাৰ কৰাটো ভুল।